METHOD if_ex_md_mrp_parameters~adjust_material_master_params.

  DATA: ls_marc TYPE marc,
        ls_mara TYPE mara,
        ls_simd TYPE /gib/dcc_simd,
        ls_simd_new TYPE /gib/dcc_simd,
        ls_disp TYPE /gib/dcc_disp,
        ls_dcc_marc TYPE /gib/dcc_marc,
        lf_ax TYPE char3,
        lf_sf TYPE /gib/dcc_safac.

*  IF im_plsc-plscn = '500'.
  IF sy-uname EQ 'PGM' OR im_plsc-plscn EQ '500'.
*# Formelwerk aktivieren
    CALL METHOD /gib/dcc_formula_mntn=>is_active.

*# Formelwerk prüfen
    IF /gib/dcc_formula_mntn=>gf_form_active NE '-'.
      SELECT SINGLE * FROM marc INTO CORRESPONDING FIELDS OF ls_marc
        WHERE werks EQ im_mt61d-werks
        AND   matnr EQ im_mt61d-matnr.

      SELECT SINGLE * FROM /gib/dcc_marc INTO ls_dcc_marc
            WHERE werks EQ im_mt61d-werks
              AND matnr EQ im_mt61d-matnr.
      CONCATENATE ls_dcc_marc-zaabc ls_dcc_marc-zaxyz INTO lf_ax.

      SELECT SINGLE * FROM mara INTO ls_mara
        WHERE matnr EQ im_mt61d-matnr.

      SELECT SINGLE * FROM /gib/dcc_disp INTO ls_disp
           WHERE werks   = ls_dcc_marc-werks
           AND   abc_grp = ls_dcc_marc-abc_grp
           AND   maaxz   = lf_ax.
      IF sy-subrc NE 0.
        SELECT SINGLE * FROM /gib/dcc_disp INTO ls_disp
             WHERE werks   = ls_dcc_marc-werks
             AND   abc_grp = ls_dcc_marc-abc_grp
             AND   maaxz   = '   '.
      ENDIF.

      MOVE-CORRESPONDING ls_marc TO ls_simd.
      CALL FUNCTION '/GIB/DCC_GET_LGRAD'
        EXPORTING
          if_matnr  = ls_marc-matnr
          if_werks  = ls_marc-werks
          if_maabc  = ls_dcc_marc-zaabc
          if_maxyz  = ls_dcc_marc-zaxyz
          if_abcgr  = ls_dcc_marc-abc_grp
          if_matkl  = ls_mara-matkl
          if_buffer = 'X'
        IMPORTING
          ef_safac  = lf_sf.

      SELECT SINGLE disvf FROM t438a INTO ls_simd-disvf
        WHERE dismm EQ ls_marc-dismm.
      ls_simd-safac = lf_sf.
      ls_simd_new = ls_simd.

      CALL FUNCTION /gib/dcc_formula_mntn=>gf_function_evaluate
        EXPORTING
          if_caller         = 'SI'
          is_mara           = ls_mara
          is_marc           = ls_marc
          is_dcc_marc       = ls_dcc_marc
          is_dcc_disp       = ls_disp
          is_dcc_simd       = ls_simd
        IMPORTING
          es_dcc_simd       = ls_simd_new
        EXCEPTIONS
          no_formula_active = 1
          invalid_formula   = 2
          OTHERS            = 3.
      IF sy-subrc <> 0.
        IF sy-subrc EQ 1.
          CALL METHOD /gib/dcc_formula_mntn=>disable.
          EXIT.
        ENDIF.
      ELSE.
        IF ls_simd_new NE ls_simd.
          MOVE-CORRESPONDING ls_simd_new TO ch_mt61d_ext.
          ch_changed = 'X'.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDIF.
ENDMETHOD.